EnigmA Amiga Run 1996 June/EnigmA AMIGA RUN 08 (1996)(G.R. Edizioni)(IT)[!][issue 1996-06][EARSAN CD VII].iso/earcd/cmdity/blcnts38.lha/BlocNotes/Install

Text File | 1996-04-12 | 6KB | 215 lines

; Install script for BlocNotes v 1.3

(set Need2 "\nBlocNotes need at least OS2.04")
(if (< (/ (getversion) 65536) 37)
  (abort Need2)
)

(set CatHelp "You can have blocnotes localized to a particular language.")
(set POPKEYHelp "With this hotkey you can popup Blocnotes main window.")
(set NOTEKEYHelp "With this hotkey you can open a new note.")
(set DIRHelp "If you specify a path, a new directory called NOTES will be created in it.\nThe notes will be stored in this directory.")
(set SCNHelp "With this library installed, Blocnotes have a better control over public screen.\nIt's recommended to install it.")
(set ASKDIRHelp "If you install blocnotes in SYS:WBStartup (default), it will be launched automatically at every startup.\nIf you want only to test BN, copy it in another place, changing the destination directory")
(set REXXHelp "These script enhance BlocNotes with new or more particular functions.\n  Scroller.rexx creates scrolling text.\n  ShowNote.rexx controls showing of notes.\n  OpenNote.pvrx is a script for use with ProVector.\n  PrepMail.rexx and SendMail.rexx permit to use Blocnotes as a simpler mailer (you need, of course, a TCP interface and a sendmail program)\n  ArchiveNote.rexx hide notes archiving them \n  Note2WB.rexx simply moves a note from a screen to workbench.")
(set GUIDEHelp "This is the doc of blocnotes in .guide format")
(set DELHelp "At startup, Blocnotes loads automatically the files not in note-format, in its directory, as notes.\nIf you select yes to this option all those file will be deleted.\nThis also applies for file you copy in notes directory while BN is running.")

(set MySou (pathonly @icon) )

(set vernum (getversion (tackon MySou "blocnotes") ) )
(set ver (/ vernum 65536))
(set rev (- vernum (* ver 65536) ) )
(set Vers (cat ver "." rev))

(welcome)

(message (cat "Welcome to BlocNotes " Vers ) " Installer script\n\n\n\n© 1996 R.Ferorelli")

(set CompleteDest
   (askdir
      (prompt "\nSelect a path where to install BlocNotes main file")
      (help ASKDIRHelp)
      (default "SYS:WBStartup")
   )
)

(copyfiles
   (prompt "Coping Blocnotes")
   (source MySou)
   (infos)
   (dest CompleteDest)
   (choices "BlocNotes")
)

; Guide file.
; *************************
(set GuideDest
   (askdir
      (prompt "\nSelect a directory where to install BlocNotes.guide file.\n")
      (help @askdir-help)
      (default "AMIGAGUIDE:")
   )
)
(copyfiles
   (prompt "Coping Blocnotes.guide")
   (help GUIDEHelp)
   (source MySou)
   (infos)
   (dest GuideDest)
   (confirm)
   (choices "BlocNotes.guide")
)

; Rexx files
; *************************
(set RexxDest
   (askdir
      (prompt "\nSelect a directory where to copy arexx scripts.\n")
      (help @askdir-help)
      (default "REXX:")
   )
)

(copyfiles
   (prompt "Coping arexx scripts")
   (help REXXHelp)
   (source MySou)
   (dest RexxDest)
   (confirm)
   (choices "scroller.rexx" "shownote.rexx" "OpenNote.pvrx" "PrepMail.rexx" "SendMail.rexx" "Archivenote.rexx" "Note2WB.rexx")
)

(copylib
   (prompt "Coping screennotify.library")
   (help SCNHelp)
   (source (tackon MySou "libs/screennotify.library"))
   (dest "LIBS:")
   (optional nofail)
   (confirm)
)

(set LangBit
   (askoptions
      (prompt "\nDo yo want to install languages")
      (help CatHelp)
      (choices "italiano")
      (default 1)
   )
)
(if (IN LangBit 0)
   (copyfiles
      (prompt "Coping the catalog 'italiano'")
      (help @copyfiles-help)
      (source (tackon MySou "catalogs/italiano/blocnotes.catalog") )
      (dest "locale:catalogs/italiano/")
   )
)

(set DestName (tackon CompleteDest "BlocNotes"))

(Set Hotkey (askstring
            (prompt "Insert Hotkey for interface popup")
            (default "control alt n")
            (help POPKEYHelp)
        )
)
(tooltype
   (settooltype "CX_POPKEY" HotKey)
   (dest DestName)
)

(Set Notekey (askstring
            (prompt "Insert Hotkey for notes popup")
            (default "control escape")
            (help NOTEKEYHelp)
        )
)
(tooltype
   (settooltype "NOTESKEY" NoteKey)
   (dest DestName)
)

(set Direct
   (askdir
      (prompt "\nSelect a path. A directory called NOTES will be created here.\n(The notes will be stored here.)")
      (help DIRHelp)
      (default "SYS:")
   )
)

(makedir (tackon Direct "NOTES"))

(tooltype
   (settooltype "DIRECTORY" (tackon Direct "NOTES"))
   (dest DestName)
)

(set DELBit
   (askbool
      (prompt "\nDo you want files, that are not notes, to be automatically deleted after being imported?")
      (help DELHelp)
      (default 0)
   )
)

(if (= DELBit 1)
   (tooltype
      (settooltype "DELETEFILES" "YES")
      (dest DestName)
   )
)

(set POPBit
   (askbool
      (prompt "\nDo you want interface window to popup at startup?")
      (help "This affects the CX_POPUP tooltype.")
      (default 0)
   )
)

(if (= POPBit 1)
   (tooltype
      (settooltype "CX_POPUP" "YES")
      (dest DestName)
   )
)

(if (= POPBit 0)
   (tooltype
      (settooltype "CX_POPUP" "NO")
      (dest DestName)
   )
)

(tooltype
   (settooltype "CMDF6" (tackon RexxDest "Prepmail.rexx"))
   (dest DestName)
)

(tooltype
   (settooltype "CMDF7" (tackon RexxDest "Sendmail.rexx"))
   (dest DestName)
)

(tooltype
   (settooltype "CMDF8" (tackon RexxDest "Note2WB.rexx"))
   (dest DestName)
)

(tooltype
   (settooltype "CMDF9" (tackon RexxDest "ArchiveNote.rexx"))
   (dest DestName)
)

(tooltype
   (settooltype "CMDF10" "'hide all'")
   (dest DestName)
)

(message "You can run the program and change other parameters directly in it.\nPlease read documentation for other options")

(set @default-dest CompleteDest )
        (exit)